Hide
Proposed solution
Revise the current CQL definition "Encounter With Severe Hypoglycemic Harm Event" by creating separate definitions for the hypoglycemic medications, initial glucose and follow-up glucose exam like so:
CURRENT LOGIC:
define "Encounter With Severe Hypoglycemic Harm Event"
"Encounter With Hypoglycemic Medication Administration" QualifyingEncounter
where exists ( ["Laboratory Test, Performed": "Glucose Lab Test Mass Per Volume"] BloodGlucoseLab1
with ["Medication, Administered": "Hypoglycemics Severe Hypoglycemia"] HypoglycemicMed
such that Global."NormalizeInterval" ( HypoglycemicMed.relevantDatetime, HypoglycemicMed.relevantPeriod ) starts 24 hours or less before or on BloodGlucoseLab1.relevantDatetime
and Global."NormalizeInterval" ( HypoglycemicMed.relevantDatetime, HypoglycemicMed.relevantPeriod ) starts during Global."HospitalizationWithObservation" ( QualifyingEncounter )
without ["Laboratory Test, Performed": "Glucose Lab Test Mass Per Volume"] BloodGlucoseLab2
such that BloodGlucoseLab2.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab2.relevantDatetime 5 minutes or less after BloodGlucoseLab1.relevantDatetime
and BloodGlucoseLab2.result > 80 'mg/dL'
where BloodGlucoseLab1.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab1.result < 40 'mg/dL' )
PROPOSED LOGIC DEFINITIONS AND FUNCTIONS:
define function "Blood Glucose Labs"(QualifyingEncounter "Encounter, Performed"):
["Laboratory Test, Performed": "Glucose lab test"] BloodGlucoseLab
where
BloodGlucoseLab.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab.result < 40 'mg/dL'
define function "Followup Glucose Lab"(QualifyingEncounter "Encounter, Performed"):
["Laboratory Test, Performed": "Glucose lab test"] FollowupBloodGlucoseLab
where FollowupBloodGlucoseLab.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and FollowupBloodGlucoseLab.result > 80 'mg/dL'
define function "Hypoglycemic Medications"(QualifyingEncounter "Encounter, Performed"):
"Hypoglycemic Medication Administration" HypoglycemicMeds
where Global."NormalizeInterval" ( HypoglycemicMeds.relevantDatetime, HypoglycemicMeds.relevantPeriod ) starts during Global."HospitalizationWithObservation" ( QualifyingEncounter )
define "Severe Hypoglycemic Harm Event":
"Denominator" QualifyingEncounter
where exists ("Blood Glucose Labs"(QualifyingEncounter) BloodGlucoseLab
with "Hypoglycemic Medications"(QualifyingEncounter) HypoglycemicMeds
such that Global."NormalizeInterval" ( HypoglycemicMeds.relevantDatetime, HypoglycemicMeds.relevantPeriod ) starts 24 hours or less before or on BloodGlucoseLab.relevantDatetime
without "Followup Glucose Lab"(QualifyingEncounter) FollowupBloodGlucoseLab
such that FollowupBloodGlucoseLab.relevantDatetime 5 minutes or less after BloodGlucoseLab.relevantDatetime )
Rationale for change
Creating separate definitions for the hypoglycemic medications, initial glucose and follow-up glucose exam and limiting each definition to the encounter timing window and applying the result filter to the lab tests may reduce the volume of data the CQL query processor has to consider when evaluating the "Severe Hypoglycemic Harm Event" expression.
Show
Proposed solution
Revise the current CQL definition "Encounter With Severe Hypoglycemic Harm Event" by creating separate definitions for the hypoglycemic medications, initial glucose and follow-up glucose exam like so:
CURRENT LOGIC:
define "Encounter With Severe Hypoglycemic Harm Event"
"Encounter With Hypoglycemic Medication Administration" QualifyingEncounter
where exists ( ["Laboratory Test, Performed": "Glucose Lab Test Mass Per Volume"] BloodGlucoseLab1
with ["Medication, Administered": "Hypoglycemics Severe Hypoglycemia"] HypoglycemicMed
such that Global."NormalizeInterval" ( HypoglycemicMed.relevantDatetime, HypoglycemicMed.relevantPeriod ) starts 24 hours or less before or on BloodGlucoseLab1.relevantDatetime
and Global."NormalizeInterval" ( HypoglycemicMed.relevantDatetime, HypoglycemicMed.relevantPeriod ) starts during Global."HospitalizationWithObservation" ( QualifyingEncounter )
without ["Laboratory Test, Performed": "Glucose Lab Test Mass Per Volume"] BloodGlucoseLab2
such that BloodGlucoseLab2.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab2.relevantDatetime 5 minutes or less after BloodGlucoseLab1.relevantDatetime
and BloodGlucoseLab2.result > 80 'mg/dL'
where BloodGlucoseLab1.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab1.result < 40 'mg/dL' )
PROPOSED LOGIC DEFINITIONS AND FUNCTIONS:
define function "Blood Glucose Labs"(QualifyingEncounter "Encounter, Performed"):
["Laboratory Test, Performed": "Glucose lab test"] BloodGlucoseLab
where
BloodGlucoseLab.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and BloodGlucoseLab.result < 40 'mg/dL'
define function "Followup Glucose Lab"(QualifyingEncounter "Encounter, Performed"):
["Laboratory Test, Performed": "Glucose lab test"] FollowupBloodGlucoseLab
where FollowupBloodGlucoseLab.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter )
and FollowupBloodGlucoseLab.result > 80 'mg/dL'
define function "Hypoglycemic Medications"(QualifyingEncounter "Encounter, Performed"):
"Hypoglycemic Medication Administration" HypoglycemicMeds
where Global."NormalizeInterval" ( HypoglycemicMeds.relevantDatetime, HypoglycemicMeds.relevantPeriod ) starts during Global."HospitalizationWithObservation" ( QualifyingEncounter )
define "Severe Hypoglycemic Harm Event":
"Denominator" QualifyingEncounter
where exists ("Blood Glucose Labs"(QualifyingEncounter) BloodGlucoseLab
with "Hypoglycemic Medications"(QualifyingEncounter) HypoglycemicMeds
such that Global."NormalizeInterval" ( HypoglycemicMeds.relevantDatetime, HypoglycemicMeds.relevantPeriod ) starts 24 hours or less before or on BloodGlucoseLab.relevantDatetime
without "Followup Glucose Lab"(QualifyingEncounter) FollowupBloodGlucoseLab
such that FollowupBloodGlucoseLab.relevantDatetime 5 minutes or less after BloodGlucoseLab.relevantDatetime )
Rationale for change
Creating separate definitions for the hypoglycemic medications, initial glucose and follow-up glucose exam and limiting each definition to the encounter timing window and applying the result filter to the lab tests may reduce the volume of data the CQL query processor has to consider when evaluating the "Severe Hypoglycemic Harm Event" expression.