-
EC eCQMs
-
Resolution: Answered
-
Moderate
-
None
-
We plan to move forward with the changes this annual update, with modifications based upon feedback
Brief Description of Measure:
CMS249: Appropriate Use of DXA Scans in Women Under 65 Years Who Do Not Meet the Risk Factor Profile for Osteoporotic Fracture:
Percentage of female patients 50 to 64 years of age without select risk factors for osteoporotic fracture who received an order for a dual-energy x-ray absorptiometry (DXA) scan during the measurement period
Description of Issue:
The intent of this measure is to exclude individuals at an increased risk for osteoporosis. A review of the literature, as well as stakeholder feedback, indicates that seven conditions not currently excluded from the measure are associated with an increased risk for osteoporosis, including exposure to chemotherapy, multiple myeloma, premature menopause, oophorectomy, eating disorder, amenorrhea and organ transplant. Therefore, we propose to add these conditions to the exclusion logic as independent risk factors.
Proposed Solution:
Below are changes to the header.
//Before
//Definition
The following risk factors may occur at any time in the patient's history or during the measurement period:
...
//After
//Definition
The following risk factors may occur at any time in the patient's history or during the measurement period:
...
Chemotherapy
Multiple myeloma
Premature menopause
Double or bilateral oophorectomy
Eating disorder
Amenorrhea
Organ transplant
Below are changes to the terminology.
//Before
(n/a)
//After
code "Left (qualifier value)": '7771000' from "SNOMEDCT" display 'Left (qualifier value)'
code "Right (qualifier value)": '24028007' from "SNOMEDCT" display 'Right (qualifier value)'
valueset "Chemotherapy": 'urn:oid:2.16.840.1.113883.3.526.3.485'
valueset "Multiple Myeloma": 'urn:oid:2.16.840.1.113883.3.464.1003.1011'
valueset "Premature Menopause": 'urn:oid:2.16.840.1.113883.3.464.1003.1013'
valueset "Bilateral Oophorectomy": 'urn:oid:2.16.840.1.113883.3.526.3.471'
valueset "Unilateral Oophorectomy Left": 'urn:oid:2.16.840.1.113883.3.464.1003.1028'
valueset "Unilateral Oophorectomy Right": 'urn:oid:2.16.840.1.113883.3.464.1003.1032'
valueset "Unilateral Oophorectomy, Unspecified Laterality": 'urn:oid:2.16.840.1.113883.3.464.1003.1035'
valueset "Evidence of Bilateral Oophorectomy": 'urn:oid:2.16.840.1.113883.3.464.1003.1048'
valueset "Eating Disorders": 'urn:oid:2.16.840.1.113883.3.464.1003.1039'
valueset "Amenorrhea": 'urn:oid:2.16.840.1.113883.3.464.1003.1022'
valueset "Bone Marrow Transplant": 'urn:oid:2.16.840.1.113883.3.666.5.336'
valueset "Major Transplant": 'urn:oid:2.16.840.1.113883.3.464.1003.198.12.1075'
valueset "Kidney Transplant": 'urn:oid:2.16.840.1.113883.3.464.1003.109.12.1012'
Below are changes to the logic.
//Before
define "Has Independent Risk Factors Applicable Any Time":
exists ( ["Diagnosis": "Type 1 Diabetes"]
union ["Diagnosis": "End Stage Renal Disease"]
union ["Diagnosis": "Osteogenesis Imperfecta"]
union ["Diagnosis": "Ankylosing Spondylitis"]
union ["Diagnosis": "Psoriatic Arthritis"]
union ["Diagnosis": "Ehlers Danlos Syndrome"]
union ["Diagnosis": "Cushings Syndrome"]
union ["Diagnosis": "Marfan's Syndrome"]
union ["Diagnosis": "Hyperparathyroidism"]
union ["Diagnosis": "Lupus"] ) IndependentRiskDiagnosis
where IndependentRiskDiagnosis.prevalencePeriod starts before
end "Measurement Period"
//After
define "Has Risk Factor Any Time in History Before End of Measurement Period":
exists ("DiagnosisInPatientHistory"( ...
union ["Diagnosis": "Type 1 Diabetes"]
union ["Diagnosis": "End Stage Renal Disease"]
union ["Diagnosis": "Osteogenesis Imperfecta"]
union ["Diagnosis": "Ankylosing Spondylitis"]
union ["Diagnosis": "Psoriatic Arthritis"]
union ["Diagnosis": "Ehlers Danlos Syndrome"]
union ["Diagnosis": "Cushings Syndrome"]
union ["Diagnosis": "Hyperparathyroidism"]
union ["Diagnosis": "Marfan's Syndrome"]
union ["Diagnosis": "Lupus"]
union ["Diagnosis": "Multiple Myeloma"]
union ["Diagnosis": "Premature Menopause"]
union ["Diagnosis": "Eating Disorders"]
union ["Diagnosis": "Amenorrhea"] ) )
or exists "ProcedureInPatientHistory"(["Procedure, Performed": "Chemotherapy"])
or "Has Double or Bilateral Oophorectomy"
or "Has Organ Transplants"
define "Has Double or Bilateral Oophorectomy":
exists ( "ProcedureInPatientHistory"(["Procedure, Performed": "Bilateral Oophorectomy"]))
or exists ( "ProcedureInPatientHistory"(["Procedure, Performed": "Evidence of Bilateral Oophorectomy"]))
or ( exists ( "ProcedureInPatientHistory"((["Procedure, Performed": "Unilateral Oophorectomy, Unspecified Laterality"] UnilateralOophorectomy
where UnilateralOophorectomy.anatomicalLocationSite ~ "Right (qualifier value)" )
union ["Procedure, Performed": "Unilateral Oophorectomy Right"] ) )
and exists ( "ProcedureInPatientHistory"((["Procedure, Performed": "Unilateral Oophorectomy, Unspecified Laterality"] UnilateralOophorectomy
where UnilateralOophorectomy.anatomicalLocationSite ~ "Left (qualifier value)" )
union ["Procedure, Performed": "Unilateral Oophorectomy Left"] ) ) )
define "Has Organ Transplants":
exists "ProcedureInPatientHistory"(["Procedure, Performed": "Major Transplant"]
union ["Procedure, Performed": "Kidney Transplant"]
union ["Procedure, Performed": "Bone Marrow Transplant"]
)
define function "ProcedureInPatientHistory"(Procedure List<"Procedure, Performed"> ):
Procedure Proc
where Global."NormalizeInterval" ( Proc.relevantDatetime, Proc.relevantPeriod ) ends on or before
end of "Measurement Period"
define function "DiagnosisInPatientHistory"(Diagnosis List<"Diagnosis"> ):
Diagnosis Dx
where Dx.prevalencePeriod starts on or before day of
end of "Measurement Period"
Rationale for Change:
Based on literature and stakeholder feedback, adding these conditions as exclusions will maximize the likelihood that individuals with increased osteoporosis risk are excluded from the measure. This change further aligns the measure with the measure intent, evidence, and stakeholder feedback.