Brief Description of Measure:

CMS136: Follow-Up Care for Children Prescribed ADHD Medication (ADD):
Percentage of children 6-12 years of age and newly dispensed a medication for attention-deficit/hyperactivity disorder (ADHD) who had appropriate follow-up care. Two rates are reported.
a. Percentage of children who had one follow-up visit with a practitioner with prescribing authority during the 30-Day Initiation Phase.
b. Percentage of children who remained on ADHD medication for at least 210 days and who, in addition to the visit in the Initiation Phase, had at least two additional follow-up visits with a practitioner within 270 days (9 months) after the Initiation Phase ended.

Description of Issue:

​The measure intent is to allow synchronous telehealth encounters for both indicators 1 and 2, and only allow asynchronous telehealth encounters (i.e., online assessments) for indicator 2 (only 1 of the 2 visits for indicator 2). The current logic could potentially allow two asynchronous telehealth encounters or a single synchronous telehealth encounter to meet indicator 2.

While NCQA wanted to expand access to care via telehealth modalities during the COVID-19 pandemic when in-person visits were restricted, behavioral health experts indicated that possible side effects of ADHD medication could include movement disorders that could be more easily detected by in-person, video, or telephone visits (as opposed to asynchronous check-ins). Stakeholders and experts thus supported maintaining the criteria of direct communication from synchronous modalities for the majority of follow-up visits in the ADD measure.

Proposed Solution:

Before

//Terminology
valueset "Telehealth Services" (2.16.840.1.113883.3.464.1003.101.12.1031)

//Logic
define "Qualifying Numerator Encounter":
  ["Encounter, Performed": "Office Visit"]
    union ["Encounter, Performed": "Hospital Observation Care - Initial"]
    union ["Encounter, Performed": "Preventive Care Services - Group Counseling"]
    union ["Encounter, Performed": "Behavioral Health Follow-up Visit"]
    union ["Encounter, Performed": "Preventive Care Services-Individual Counseling"]
    union ( ["Encounter, Performed": "Psychotherapy and Pharmacologic Management"] PsychPharmMgmt
        where exists ( PsychPharmMgmt.facilityLocations Location
            where Location.code in "Ambulatory"
        )
    )
    union ["Encounter, Performed": "Observation care discharge day management (This code is to be utilized to report all services provided to a patient on discharge from outpatient hospital observation status if the discharge is on other than the initial date of observation status. To report services to a patient designated as observation status or inpatient status and discharged on the same date, use the codes for Observation or Inpatient Care Services [including Admission and Discharge Services, 99234-99236 as appropriate.])"]
    union ["Encounter, Performed": "Outpatient Consultation"]
    union ["Encounter, Performed": "Home Healthcare Services"]
    union ["Encounter, Performed": "Preventive Care Services, Initial Office Visit, 0 to 17"]
    union ["Encounter, Performed": "Preventive Care, Established Office Visit, 0 to 17"]
    union ["Encounter, Performed": "Psych Visit - Diagnostic Evaluation"]
    union ["Encounter, Performed": "Psych Visit - Psychotherapy"]
    union ["Encounter, Performed": "Telephone Visits"]
    union ["Encounter, Performed": "Online Assessments"]

define "Telehealth Services or Telephone Management Encounter":
["Encounter, Performed": "Telehealth Services"] TelehealthEncounter
  with "First ADHD Medication Dispensed during Intake Period" InitialADHDMedication
    such that TelehealthEncounter.relevantPeriod starts 31 days or more after day of InitialADHDMedication.relevantDatetime
      and TelehealthEncounter.relevantPeriod starts 300 days or less after day of InitialADHDMedication.relevantDatetime

After

//Terminology - remove valueset "Telehealth Services" (2.16.840.1.113883.3.464.1003.101.12.1031)

//Logic
Remove "Online Assessments" from the following definition -
define "Qualifying Numerator Encounter":
  ["Encounter, Performed": "Office Visit"]
    union ["Encounter, Performed": "Hospital Observation Care - Initial"]
    union ["Encounter, Performed": "Preventive Care Services - Group Counseling"]
    union ["Encounter, Performed": "Behavioral Health Follow-up Visit"]
    union ["Encounter, Performed": "Preventive Care Services-Individual Counseling"]
    union ( ["Encounter, Performed": "Psychotherapy and Pharmacologic Management"] PsychPharmMgmt
        where exists ( PsychPharmMgmt.facilityLocations Location
            where Location.code in "Ambulatory"
        )
    )
    union ["Encounter, Performed": "Observation care discharge day management (This code is to be utilized to report all services provided to a patient on discharge from outpatient hospital observation status if the discharge is on other than the initial date of observation status. To report services to a patient designated as observation status or inpatient status and discharged on the same date, use the codes for Observation or Inpatient Care Services [including Admission and Discharge Services, 99234-99236 as appropriate.])"]
    union ["Encounter, Performed": "Outpatient Consultation"]
    union ["Encounter, Performed": "Home Healthcare Services"]
    union ["Encounter, Performed": "Preventive Care Services, Initial Office Visit, 0 to 17"]
    union ["Encounter, Performed": "Preventive Care, Established Office Visit, 0 to 17"]
    union ["Encounter, Performed": "Psych Visit - Diagnostic Evaluation"]
    union ["Encounter, Performed": "Psych Visit - Psychotherapy"]
    union ["Encounter, Performed": "Telephone Visits"]

Replace definition "Telehealth Services or Telephone Management Encounter" with the following definition:
define "Online Assessment 31 to 300 Days into Continuation and Maintenance Phase":
["Encounter, Performed": "Online Assessments"] OnlineAssessment
  with "First ADHD Medication Prescribed during Intake Period" InitialADHDMedication
    such that OnlineAssessment.relevantPeriod starts during day of Interval[InitialADHDMedication.authorDatetime + 31 days, InitialADHDMedication.authorDatetime + 300 days]

Rationale for Change:

​The goal of this change is to align with the measure intent.