Brief Description of Measure:

​CMS136: Follow-Up Care for Children Prescribed ADHD Medication (ADD):
Percentage of children 6-12 years of age and newly dispensed a medication for attention-deficit/hyperactivity disorder (ADHD) who had appropriate follow-up care. Two rates are reported.
a. Percentage of children who had one follow-up visit with a practitioner with prescribing authority during the 30-Day Initiation Phase.
b. Percentage of children who remained on ADHD medication for at least 210 days and who, in addition to the visit in the Initiation Phase, had at least two additional follow-up visits with a practitioner within 270 days (9 months) after the Initiation Phase ended.

Description of Issue:

​​The current Intake Period is a 5-month period (beginning 90 days prior to the start of the measurement period and ending 60 days after the start of the measurement period). We would like to extend it to a 12-month period (March 1 of the year prior to the measurement period and ending the last calendar day of February of the measurement period). 
A 12-month period ensures that the measure assesses follow-up for individuals who are newly prescribed ADHD medication at any point within a year, rather than only assessing individuals who are newly prescribed ADHD medication in the Fall/Winter.

Proposed Solution:

​Before

//Header: Definition
Intake Period: The five-month period starting 90 days prior to the start of the measurement period and ending 60 days after the start of the measurement period.

//Logic

define "Initial Population 1":
exists ["Patient Characteristic Birthdate": "Birth date"] BirthDate
  where Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, start of "Measurement Period" ) in Interval[6, 12 )
    and exists ( "Qualifying Encounter" )
    and "First ADHD Medication Dispensed during Intake Period" is not null

define "Initial Population 2":
exists ["Patient Characteristic Birthdate": "Birth date"] BirthDate
  where Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, start of "Measurement Period" ) in Interval[6, 12 )
    and exists ( "Qualifying Encounter" )
    and "First ADHD Medication Dispensed during Intake Period" is not null
    and "Has ADHD Cumulative Medication Duration Greater Than or Equal to 210 Days"

define "First ADHD Medication Dispensed during Intake Period":
First(["Medication, Dispensed": "ADHD Medications"] FirstADHDMedication
    where Global."EarliestOf"(FirstADHDMedication.relevantDatetime, FirstADHDMedication.relevantPeriod)during Interval[start of "Measurement Period" - 90 days, start of "Measurement Period" + 60 days]
    sort by start of Global."NormalizeInterval"(relevantDatetime, relevantPeriod)
)

After

//Header: Definition
Intake Period: The twelve-month period starting March 1 of the year prior to the measurement period and ending the last calendar day of February of the measurement period.

//Logic - new definitions to be created
define "Intake Period":
  Interval["March 1 of Year Prior to Measurement Period", "Last Calendar Day of February of Measurement Period"]

define "Last Calendar Day of February of Measurement Period":
  ( DateTime(year from start of "Measurement Period", 3, 1, 23, 59, 59, 0, 0)) - 1 day

define "March 1 of Year Prior to Measurement Period":
  DateTime((year from start of "Measurement Period" - 1), 3, 1, 0, 0, 0, 0, 0)

//Logic - existing definitions to be updated
define "Initial Population 1":
exists ["Patient Characteristic Birthdate": "Birth date"] BirthDate
 where Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, start of "Intake Period" ) >= 6
    and Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime,
    end of "Intake Period" ) <= 12...

define "Initial Population 2":
exists ["Patient Characteristic Birthdate": "Birth date"] BirthDate
 where Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, start of "Intake Period" ) >= 6
    and Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime,
    end of "Intake Period" ) <= 12...

define "First ADHD Medication Dispensed during Intake Period":
... during "Intake Period"
    sort by start of Global."NormalizeInterval"(relevantDatetime, relevantPeriod)
)

Rationale for Change:

​The goal of this change is to bring the measure into alignment with the measure intent and ensure that the measure assesses follow-up for individuals who are newly prescribed ADHD medication at any point within a year.