Brief Description of Measure:
​CMS122: Diabetes: Hemoglobin A1c (HbA1c) Poor Control (>9%)

CMS124: Cervical Cancer Screening

CMS125: Breast Cancer Screening

CMS130: Colorectal Cancer Screening

CMS131: Diabetes: Eye Exam

CMS134: Diabetes: Medical Attention for Nephropathy

CMS156: Use of High-Risk Medications in Older Adults

CMS165: Controlling High Blood Pressure

Description of Issue:

Implementers (CQM-3065) expressed interest in seeing ICD-10-CM Z-code, Z51.5, included in the exclusion.

Below is the current specification:

code system "LOINC": 'urn:oid:2.16.840.1.113883.6.1'

value set "Palliative Care Encounter": 'urn:oid:2.16.840.1.113883.3.464.1003.101.12.1090'
value set "Palliative Care Intervention": 'urn:oid:2.16.840.1.113883.3.464.1003.198.12.1135'

code "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)": '71007-9' from "LOINC" display 'Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)'

define "Palliative Care in the Measurement Period":
exists ( ["Assessment, Performed": "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)"] PalliativeAssessment
where Global."NormalizeInterval"(PalliativeAssessment.relevantDatetime, PalliativeAssessment.relevantPeriod) overlaps "Measurement Period" )
or exists ( ["Encounter, Performed": "Palliative Care Encounter"] PalliativeEncounter
where PalliativeEncounter.relevantPeriod overlaps "Measurement Period" )
or exists ( ["Intervention, Performed": "Palliative Care Intervention"] PalliativeIntervention
where Global."NormalizeInterval"(PalliativeIntervention.relevantDatetime, PalliativeIntervention.relevantPeriod) overlaps "Measurement Period" )

Proposed Solution:

For the palliative care exclusion specification, we propose adding a new "Diagnosis" data type using ICD-10-CM code Z51.5 ([Z51.5] Encounter for palliative care).

Below is the proposed specification:

code system "ICD10CM": 'urn:oid:2.16.840.1.113883.6.90'
code system "LOINC": 'urn:oid:2.16.840.1.113883.6.1'

value set "Palliative Care Encounter": 'urn:oid:2.16.840.1.113883.3.464.1003.101.12.1090'
value set "Palliative Care Intervention": 'urn:oid:2.16.840.1.113883.3.464.1003.198.12.1135'

code "Encounter for palliative care": 'Z51.5' from "ICD10CM" display 'Encounter for palliative care'
code "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)": '71007-9' from "LOINC" display 'Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)'

define "Palliative Care in the Measurement Period":
exists ( ["Assessment, Performed": "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)"] PalliativeAssessment
where Global."NormalizeInterval"(PalliativeAssessment.relevantDatetime, PalliativeAssessment.relevantPeriod) overlaps "Measurement Period" )
or exists (["Diagnosis": "Encounter for palliative care"] PalliativeDiagnosis
where PalliativeDiagnosis.prevalencePeriod overlaps "Measurement Period")
or exists ( ["Encounter, Performed": "Palliative Care Encounter"] PalliativeEncounter
where PalliativeEncounter.relevantPeriod overlaps "Measurement Period" )
or exists ( ["Intervention, Performed": "Palliative Care Intervention"] PalliativeIntervention
where Global."NormalizeInterval"(PalliativeIntervention.relevantDatetime, PalliativeIntervention.relevantPeriod) overlaps "Measurement Period" )

We also propose adding 3 SNOMED-CT finding codes to an existing value set, Palliative Care Intervention (Grouping OID: 2.16.840.1.113883.3.464.1003.198.12.1135), which maps to "Intervention, Performed":

• 305686008, Seen by palliative care physician (finding)
• 305824005, Seen by palliative care medicine service (finding)
• 441874000, Seen by palliative care service (finding)

Rationale for Change:

​These changes would reduce implementation burden for eligible clinicians and allow them to identify patients meeting measure criteria using their current documentation workflows.