The measure Median Time to Pain Medication for Patients with a Diagnosis of Sickle Cell Disease (SCD) with Vaso-Occlusive Episode (VOE) Version 0.0.000 QDM v5.6 was imported from the MAT tool but now gives an error in the CQL editor.

Error:

• Row: 9, Col:0: VSAC: 0:57 | Request failed with status code 401 for oid = 2.16.840.1.114222.4.11.837 location = 9:0-9:57
• Row: 11, Col:0: VSAC: 0:59 | Request failed with status code 401 for oid = 2.16.840.1.114222.4.11.3591 location = 11:0-11:59
• Row: 10, Col:0: VSAC: 0:67 | Request failed with status code 401 for oid = 2.16.840.1.113762.1.4.1 location = 10:0-10:67
• Row: 7, Col:0: VSAC: 0:76 | Request failed with status code 401 for oid = 2.16.840.1.113762.1.4.1160.43 location = 7:0-7:76
• Row: 12, Col:0: VSAC: 0:52 | Request failed with status code 401 for oid = 2.16.840.1.114222.4.11.836 location = 12:0-12:52
• Row: 8, Col:0: VSAC: 0:114 | Request failed with status code 401 for oid = 2.16.840.1.113883.3.464.1003.101.12.1010 location = 8:0-8:114
• Row: 13, Col:0: VSAC: 0:98 | Request failed with status code 401 for oid = 2.16.840.1.113762.1.4.1160.42 location = 13:0-13:98
   
  CQL code:
   
   
  library HSAGCommonLibrary version '0.0.000'
   
  using QDM version '5.6'
   
  include MATGlobalCommonFunctionsQDM version '8.0.000' called Global
   
  valueset "Analgesics for Acute Pain": 'urn:oid:2.16.840.1.113762.1.4.1160.43'
  valueset "Emergency Department Evaluation and Management Visit": 'urn:oid:2.16.840.1.113883.3.464.1003.101.12.1010'
  valueset "Ethnicity": 'urn:oid:2.16.840.1.114222.4.11.837'
  valueset "ONC Administrative Sex": 'urn:oid:2.16.840.1.113762.1.4.1'
  valueset "Payer Type": 'urn:oid:2.16.840.1.114222.4.11.3591'
  valueset "Race": 'urn:oid:2.16.840.1.114222.4.11.836'
  valueset "Sickle Cell Disease with Vaso Occlusive Episode": 'urn:oid:2.16.840.1.113762.1.4.1160.42'
   
  parameter "Measurement Period" Interval<DateTime>
   
  context Patient
   
  define "SDE Ethnicity":
  ["Patient Characteristic Ethnicity": "Ethnicity"]
   
  define "SDE Payer":
  ["Patient Characteristic Payer": "Payer Type"]
   
  define "SDE Race":
  ["Patient Characteristic Race": "Race"]
   
  define "SDE Sex":
  ["Patient Characteristic Sex": "ONC Administrative Sex"]
   
  define "ED Encounter with Principal Diagnosis of SCD with VOE":
  ["Encounter, Performed": "Emergency Department Evaluation and Management Visit"] EDEncounter
  with EDEncounter.diagnoses EncounterDiagnosis
  such that EncounterDiagnosis.code in "Sickle Cell Disease with Vaso Occlusive Episode"
  and EncounterDiagnosis.rank = 1
   
  define "ED Encounter for SCD with VOE with Pain Medication Administered":
  "ED Encounter with Principal Diagnosis of SCD with VOE" SCDwVOEEncounter
  with ["Medication, Administered": "Analgesics for Acute Pain"] PainMed
  such that start of Global.NormalizeInterval ( PainMed.relevantDatetime, PainMed.relevantPeriod ) during SCDwVOEEncounter.relevantPeriod
   
  define "Initial Population":
  "ED Encounter for SCD with VOE with Pain Medication Administered" EDEncounter
  where EDEncounter.relevantPeriod starts during "Measurement Period"
   
  define function "FirstPainMedicationAdministration"(EDEncounterForSCDwVOE "Encounter, Performed"):
  First(["Medication, Administered": "Analgesics for Acute Pain"] PainMed
  where start of Global.NormalizeInterval(PainMed.relevantDatetime, PainMed.relevantPeriod) during EDEncounterForSCDwVOE.relevantPeriod
  sort by relevantDatetime
  )
   
  define function "NumberOfMinutesBetweenEDArrivalAndFirstPainMedicationAdministration"(EDEncounterForSCDwVOE "Encounter, Performed"):
  duration in minutes of Interval[Global."EmergencyDepartmentArrivalTime" ( EDEncounterForSCDwVOE ), start of Global."NormalizeInterval" ( "FirstPainMedicationAdministration"(EDEncounterForSCDwVOE).relevantDatetime, "FirstPainMedicationAdministration"
        (EDEncounterForSCDwVOE).relevantPeriod )]