library CesareanBirthFHIR version '0.1.000'

using QICore version '4.1.1'

include CQMCommon version '1.1.000' called CQMCommon
include FHIRHelpers version '4.2.000' called FHIRHelpers
include SupplementalDataElements version '3.2.000' called SDE
include PCMaternal version '5.7.000' called PCMaternal
include QICoreCommon version '1.3.000' called QICoreCommon

codesystem "LOINC": 'http://loinc.org' 

valueset "Abnormal Presentation": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1045.105' 
valueset "Cesarean Birth": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.282' 
valueset "Delivery of Singleton": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1045.99' 
valueset "Delivery Procedures": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1045.59' 
valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307' 
valueset "Estimated Gestational Age at Delivery": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1045.26' 
valueset "Placenta Previa or Accreta or Vasa Previa":  'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.37'
valueset "37 to 42 Plus Weeks Gestation": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.68'


code "[#] Births.preterm": '11637-6' from "LOINC" display '[#] Births.preterm'
code "[#] Births.term": '11639-2' from "LOINC" display '[#] Births.term'
code "[#] Parity": '11977-6' from "LOINC" display '[#] Parity'
code "[#] Pregnancies": '11996-6' from "LOINC" display '[#] Pregnancies'
code "Date and time of obstetric delivery": '93857-1' from "LOINC" display 'Date and time of obstetric delivery'

parameter "Measurement Period" Interval<DateTime>

context Patient

define "Delivery Encounter with Abnormal Presentation, Placenta Previa, Placenta Accreta or Vasa Previa":
  "Encounter with Abnormal Presentation"
                    union "Encounter with Placenta Previa, Placenta Accreta or Vasa Previa"

define "Delivery Encounter with Calculated Gestational Age Greater than or Equal to 37 Weeks":
  PCMaternal."Delivery Encounter with Age Range" DeliveryEncounter
        where  DeliveryEncounter.calculatedGestationalAge ( ) >= 37

define "Delivery Encounter with Estimated Gestational Age Greater than or Equal to 37 Weeks":
  PCMaternal."Delivery Encounter with Age Range" DeliveryEncounter
        where DeliveryEncounter.calculatedGestationalAge (  ) is null
          and DeliveryEncounter.lastEstimatedGestationalAge (  ) >= 37 weeks

define "Delivery Encounter with Gestational Age Greater than or Equal to 37 Weeks":
  "Delivery Encounter with Calculated Gestational Age Greater than or Equal to 37 Weeks"
      union "Delivery Encounter with Estimated Gestational Age Greater than or Equal to 37 Weeks"
      union "Delivery Encounter with Gestational Age Greater than or Equal to 37 Weeks Based on Coding"

define "Delivery Encounter with Gestational Age Greater than or Equal to 37 Weeks Based on Coding":
PCMaternal."Delivery Encounter with Age Range" DeliveryEncounter
let CGA:   DeliveryEncounter.calculatedGestationalAge ( ),
EGA:   DeliveryEncounter.lastEstimatedGestationalAge ( )
where CGA is null
and EGA is null
    and DeliveryEncounter.encounterDiagnosis().code in "37 to 42 Plus Weeks Gestation"
	    

  
define "Denominator":
  "Singleton Delivery Encounters at 37 Plus Weeks Gravida 1 Parity 0, No Previous Births"

define "Denominator Exclusions":
  "Delivery Encounter with Abnormal Presentation, Placenta Previa, Placenta Accreta or Vasa Previa"

define "Initial Population":
  PCMaternal."Delivery Encounter with Age Range"

define "Numerator":
  "Delivery Encounter with Cesarean Birth"

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Variable Calculated Gestational Age":
  PCMaternal."Variable Calculated Gestational Age"

define "Delivery Encounter with Cesarean Birth":
  "Singleton Delivery Encounters at 37 Plus Weeks Gravida 1 Parity 0, No Previous Births" QualifyingEncounter
        with ["Procedure": "Cesarean Birth"] CSection
          such that CSection.performed.toInterval ()  during QualifyingEncounter.hospitalizationWithEDOBTriageObservation()
            and CSection.status = 'completed'

define "Encounter with Placenta Previa, Placenta Accreta or Vasa Previa":
  "Singleton Delivery Encounters at 37 Plus Weeks Gravida 1 Parity 0, No Previous Births" QualifyingEncounter
        where QualifyingEncounter.encounterDiagnosis().code in "Placenta Previa or Accreta or Vasa Previa"

define "Singleton Delivery Encounters at 37 Plus Weeks Gravida 1 Parity 0, No Previous Births":
  ( "Delivery Encounter with Gestational Age Greater than or Equal to 37 Weeks"
      intersect "Encounter with Singleton Delivery" ) SingletonEncounterGE37Weeks
        where ( ( SingletonEncounterGE37Weeks.lastGravida()= 1 )
            or ( SingletonEncounterGE37Weeks.lastParity ()= 0 )
            or ( ( SingletonEncounterGE37Weeks.lastHistoryPretermBirth ()= 0 )
                and ( SingletonEncounterGE37Weeks.lastHistoryTermBirth ()= 0 )
            )
        )

define "Encounter with Abnormal Presentation":
  "Singleton Delivery Encounters at 37 Plus Weeks Gravida 1 Parity 0, No Previous Births" QualifyingEncounter
        let LastAbnormalPresentation: Last(["Observation": "Abnormal Presentation"] AbnormalPresentation
          where AbnormalPresentation.effective.earliest () before or on QualifyingEncounter.lastTimeOfDelivery()
            and AbnormalPresentation.status in { 'final', 'amended', 'corrected' }
          sort by effective.earliest ()
        )
        where QualifyingEncounter.encounterDiagnosis().code in "Abnormal Presentation"
          or  LastAbnormalPresentation.effective.earliest ( ) during QualifyingEncounter.period

define "Encounter with Singleton Delivery":
  PCMaternal."Delivery Encounter with Age Range" DeliveryEncounter
    where DeliveryEncounter.encounterDiagnosis( ).code in "Delivery of Singleton"
   //       and EncounterDiagnoses.verificationStatus  ~ FHIRCommon."confirmed"

define fluent function lastGravida (TheEncounter Encounter ):
  Last(["Observation": "[#] Pregnancies"] Gravida
  where Gravida.value is not null
        and Gravida.status in { 'final', 'amended', 'corrected' }
        and Gravida.effective.earliest() 42 weeks or less before TheEncounter.lastTimeOfDelivery()
      sort by effective.earliest( )
  ).value as Integer

define fluent function lastHistoryPretermBirth (TheEncounter Encounter ):
  Last(["Observation": "[#] Births.preterm"] PretermBirth
      where PretermBirth.effective.earliest() 42 weeks or less before TheEncounter.lastTimeOfDelivery()
        and PretermBirth.status in { 'final', 'amended', 'corrected' }
        and PretermBirth.value is not null
      sort by effective.earliest()
  ).value as Integer

define fluent function lastHistoryTermBirth (TheEncounter Encounter ):
  Last(["Observation": "[#] Births.term"] TermBirth
      where TermBirth.effective.earliest() 42 weeks or less before TheEncounter.lastTimeOfDelivery()
        and TermBirth.status in { 'final', 'amended', 'corrected' }
        and TermBirth.value is not null
      sort by effective.earliest()
  ).value as Integer

define fluent function lastParity(TheEncounter Encounter ):
  Last(["Observation": "[#] Parity"] Parity
      where Parity.effective.earliest() 42 weeks or less before TheEncounter.lastTimeOfDelivery()
        and Parity.status in { 'final', 'amended', 'corrected' }
        and Parity.value is not null
      sort by effective.earliest( )
  ).value as Integer