-
EC eCQMs
-
Resolution: Answered
-
Moderate
-
None
-
We plan to move forward with the proposed change during this annual update.
Brief Description of Measure:
CMS124: Cervical Cancer Screening:
Percentage of women 21-64 years of age who were screened for cervical cancer using either of the following criteria:
- Women age 21-64 who had cervical cytology performed within the last 3 years
- Women age 30-64 who had cervical human papillomavirus (HPV) testing performed within the last 5 years
CMS130: Colorectal Cancer Screening:
Percentage of adults 50-75 years of age who had appropriate screening for colorectal cancer
Description of Issue:
There is a one second difference from the intended screening timeframes indicated in CMS134 and CMS130.
In CMS124, the logic for "Cervical Cytology Within 3 Years" uses the syntax "3 years or less on or before the end of measurement period", which could count 12/31/2019 11:59PM when the end of the measurement period is 12/31/2022 11:59PM. The intent of the measure is to count pap tests during the measurement period or two years prior to the measurement, which is 1/1/2020 12:00AM -12/31/2022 11:59PM.
Similarly, in CMS130, the logic for "CT Colonography Performed" uses the syntax "5 years or less on or before end of measurement period", which could count 12/31/2017 11:59PM when the end of the measurement period is 12/31/2022 11:59PM. The intent of the measure is to count CT colonography during the measurement period or 4 years prior to the measurement period, which is 1/1/2018 12:00AM - 12/31/2022 11:59PM.
To improve the precision of the screening timeframe, we propose to specify with "intervals" instead of using the syntax "X years or less on or before...".
Proposed Solution:
CMS124
Current:
Cervical Cytology Within 3 Years =
["Laboratory Test, Performed": "Pap Test"] CervicalCytology
where Global."LatestOf" ( CervicalCytology.relevantDatetime, CervicalCytology.relevantPeriod ) 3 years or less on or before
end of "Measurement Period"
and CervicalCytology.result is not null
HPV Test Within 5 Years for Women Age 30 and Older =
["Laboratory Test, Performed": "HPV Test"] HPVTest
with ["Patient Characteristic Birthdate": "Birth date"] BirthDate
such that Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, HPVTest.relevantDatetime ) >= 30
where Global."LatestOf" ( HPVTest.relevantDatetime, HPVTest.relevantPeriod ) 5 years or less on or before
end of "Measurement Period"
and HPVTest.result is not null
Proposed:
Cervical Cytology Within 3 Years =
["Laboratory Test, Performed": "Pap Test"] CervicalCytology
where Global."LatestOf" ( CervicalCytology.relevantDatetime, CervicalCytology.relevantPeriod ) during day of Interval[start of "Measurement Period" - 2 years,
end of "Measurement Period"]
and CervicalCytology.result is not null
HPV Test Within 5 Years for Women Age 30 and Older =
["Laboratory Test, Performed": "HPV Test"] HPVTest
with ["Patient Characteristic Birthdate": "Birth date"] BirthDate
such that Global."CalendarAgeInYearsAt" ( BirthDate.birthDatetime, HPVTest.relevantDatetime ) >= 30
where Global."LatestOf" ( HPVTest.relevantDatetime, HPVTest.relevantPeriod ) during day of Interval[start of "Measurement Period" - 4 years,
end of "Measurement Period"]
and HPVTest.result is not null
CMS130
Current:
Fecal Immunochemical Test DNA Performed =
["Laboratory Test, Performed": "FIT DNA"] FitDNA
where FitDNA.result is not null
and Global."LatestOf" ( FitDNA.relevantDatetime, FitDNA.relevantPeriod ) 3 years or less on or before
end of "Measurement Period"
CT Colonography Performed =
["Diagnostic Study, Performed": "CT Colonography"] Colonography
where Global."NormalizeInterval" ( Colonography.relevantDatetime, Colonography.relevantPeriod ) ends 5 years or less on or before
end of "Measurement Period"
Flexible Sigmoidoscopy Performed =
["Procedure, Performed": "Flexible Sigmoidoscopy"] FlexibleSigmoidoscopy
where Global."NormalizeInterval" ( FlexibleSigmoidoscopy.relevantDatetime, FlexibleSigmoidoscopy.relevantPeriod ) ends 5 years or less on or before
end of "Measurement Period"
Colonoscopy Performed =
["Procedure, Performed": "Colonoscopy"] Colonoscopy
where Global."NormalizeInterval" ( Colonoscopy.relevantDatetime, Colonoscopy.relevantPeriod ) ends 10 years or less on or before
end of "Measurement Period"
Proposed:
Fecal Immunochemical Test DNA Performed =
["Laboratory Test, Performed": "FIT DNA"] FitDNA
where FitDNA.result is not null
and Global."LatestOf" ( FitDNA.relevantDatetime, FitDNA.relevantPeriod ) during day of Interval[start of "Measurement Period" - 2 years,
end of "Measurement Period"]
CT Colonography Performed =
["Diagnostic Study, Performed": "CT Colonography"] Colonography
where Global."NormalizeInterval" ( Colonography.relevantDatetime, Colonography.relevantPeriod ) ends during day of Interval[start of "Measurement Period" - 4 years,
end of "Measurement Period"]
Flexible Sigmoidoscopy Performed =
["Procedure, Performed": "Flexible Sigmoidoscopy"] FlexibleSigmoidoscopy
where Global."NormalizeInterval" ( FlexibleSigmoidoscopy.relevantDatetime, FlexibleSigmoidoscopy.relevantPeriod ) ends during day of Interval[start of "Measurement Period" - 4 years,
end of "Measurement Period"]
Colonoscopy Performed =
["Procedure, Performed": "Colonoscopy"] Colonoscopy
where Global."NormalizeInterval" ( Colonoscopy.relevantDatetime, Colonoscopy.relevantPeriod ) ends during day of Interval[start of "Measurement Period" - 9 years,
end of "Measurement Period"]
Rationale for Change:
This change would precisely express the intended screening timeframe required by the measures.