-
EC eCQMs
-
Resolution: Answered
-
Moderate
-
None
-
We plan to move forward with the proposed change during this annual update.
-
Brief Description of Measure:
CMS122: Diabetes: Hemoglobin A1c (HbA1c) Poor Control (>9%)
Percentage of patients 18-75 years of age with diabetes who had hemoglobin A1c > 9.0% during the measurement period
CMS125: Breast Cancer Screening
Percentage of women 50-74 years of age who had a mammogram to screen for breast cancer in the 27 months prior to the end of the Measurement Period
CMS130: Colorectal Cancer Screening
Percentage of adults 50-75 years of age who had appropriate screening for colorectal cancer
CMS131: Diabetes: Eye Exam
Percentage of patients 18-75 years of age with diabetes and an active diagnosis of retinopathy in any part of the measurement period who had a retinal or dilated eye exam by an eye care professional during the measurement period or diabetics with no diagnosis of retinopathy in any part of the measurement period who had a retinal or dilated eye exam by an eye care professional during the measurement period or in the 12 months prior to the measurement period
CMS134: Diabetes: Medical Attention for Nephropathy
The percentage of patients 18-75 years of age with diabetes who had a nephropathy screening test or evidence of nephropathy during the measurement period
CMS165: Controlling High Blood Pressure
Percentage of patients 18-85 years of age who had a diagnosis of essential hypertension starting before and continuing into, or starting during the first six months of the measurement period, and whose most recent blood pressure was adequately controlled (<140/90mmHg) during the measurement period
Description of Issue:
QDM datatype Device, Applied will be retired in QDM v5.6. Since QDM v5.6 Section 6.1 (https://ecqi.healthit.gov/sites/default/files/QDM-v5.6-508.pdf) recommends "Assessment, Performed" as a replacement option for referencing an observation about device usage, stability, and presence.
Below is the current specification:
//Terminology
value set "Frailty Device" (2.16.840.1.113883.3.464.1003.118.12.1300)
value set "Frailty Diagnosis" (2.16.840.1.113883.3.464.1003.113.12.1074)
value set "Frailty Encounter" (2.16.840.1.113883.3.464.1003.101.12.1088)
value set "Frailty Symptom" (2.16.840.1.113883.3.464.1003.113.12.1075)
//Logic
define "Has Criteria Indicating Frailty":
exists ( ["Device, Order": "Frailty Device"] FrailtyDeviceOrder
where FrailtyDeviceOrder.authorDatetime during "Measurement Period" )
or exists ( ["Device, Applied": "Frailty Device"] FrailtyDeviceApplied
where Global."NormalizeInterval" ( FrailtyDeviceApplied.relevantDatetime, FrailtyDeviceApplied.relevantPeriod ) overlaps "Measurement Period" )
or exists ( ["Diagnosis": "Frailty Diagnosis"] FrailtyDiagnosis
where FrailtyDiagnosis.prevalencePeriod overlaps "Measurement Period" )
or exists ( ["Encounter, Performed": "Frailty Encounter"] FrailtyEncounter
where FrailtyEncounter.relevantPeriod overlaps "Measurement Period" )
or exists ( ["Symptom": "Frailty Symptom"] FrailtySymptom
where FrailtySymptom.prevalencePeriod overlaps "Measurement Period" )
Proposed Solution:
The proposed logic replaces ["Device, Applied": "Frailty Device"] with ["Assessment, Performed": "Medical equipment used"] requiring a result of "Frailty Device". Since recency is an important aspect for frailty device usage, assessments are restricted to those completed during the measurement period.
Please note that LOINC code 98181-1 "Medical equipment used" (https://loinc.org/98181-1/) is not yet released in VSAC as of 8/19/2021, but will be required to implement this change.
Below is the proposed specification:
//Terminology
code "Medical equipment used": '98181-1' from "LOINC" display 'Medical equipment used'
value set "Frailty Device" (2.16.840.1.113883.3.464.1003.118.12.1300)
value set "Frailty Diagnosis" (2.16.840.1.113883.3.464.1003.113.12.1074)
value set "Frailty Encounter" (2.16.840.1.113883.3.464.1003.101.12.1088)
value set "Frailty Symptom" (2.16.840.1.113883.3.464.1003.113.12.1075)
//Logic
define "Has Criteria Indicating Frailty":
exists ( ["Device, Order": "Frailty Device"] FrailtyDeviceOrder
where FrailtyDeviceOrder.authorDatetime during "Measurement Period" )
or exists ( ["Assessment, Performed": "Medical equipment used"] EquipmentUse
where EquipmentUse.result in "Frailty Device"
and Global."NormalizeInterval" ( EquipmentUse.relevantDatetime, EquipmentUse.relevantPeriod ) ends during "Measurement Period" )
or exists ( ["Diagnosis": "Frailty Diagnosis"] FrailtyDiagnosis
where FrailtyDiagnosis.prevalencePeriod overlaps "Measurement Period" )
or exists ( ["Encounter, Performed": "Frailty Encounter"] FrailtyEncounter
where FrailtyEncounter.relevantPeriod overlaps "Measurement Period" )
or exists ( ["Symptom": "Frailty Symptom"] FrailtySymptom
where FrailtySymptom.prevalencePeriod overlaps "Measurement Period" )
Rationale for Change:
The proposed changes provide a new approach for identifying frailty device usage as replacement of the retiring QDM datatype.