-
EC eCQMs
-
Resolution: Answered
-
Moderate
-
None
-
We plan to move forward with the proposed change during this annual update. We have noted existing concerns with the current codes in the measure.
Brief Description of Measure:
CMS122: Diabetes: Hemoglobin A1c (HbA1c) Poor Control (>9%)
Percentage of patients 18-75 years of age with diabetes who had hemoglobin A1c > 9.0% during the measurement period
CMS125: Breast Cancer Screening
Percentage of women 50-74 years of age who had a mammogram to screen for breast cancer in the 27 months prior to the end of the Measurement Period
CMS130: Colorectal Cancer Screening
Percentage of adults 50-75 years of age who had appropriate screening for colorectal cancer
CMS134: Diabetes: Medical Attention for Nephropathy
The percentage of patients 18-75 years of age with diabetes who had a nephropathy screening test or evidence of nephropathy during the measurement period
CMS165: Controlling High Blood Pressure
Percentage of patients 18-85 years of age who had a diagnosis of essential hypertension starting before and continuing into, or starting during the first six months of the measurement period, and whose most recent blood pressure was adequately controlled (<140/90mmHg) during the measurement period.
Description of Issue:
The measures allow telehealth encounters as additional qualifying encounters in the Initial Population. There is room to simplify the measure logic by including telehealth encounters in the library definition AdultOutpatientEncounters."Qualifying Encounters".
Proposed Solution:
To simplify repeated logic, CMS125, CMS130, and CMS165 will use this library definition which will include "Telephone Visits" and "Online Assessments"; while CMS122 and CMS134 will stop using the library definition and in replacement use a standalone "Qualifying Encounters" definition that now includes "Telephone Visits".
The following change applies to the AdultOutpatientEncounters library.
CURRENT:
"Qualifying Encounters":
( ["Encounter, Performed": "Office Visit"]
union ["Encounter, Performed": "Annual Wellness Visit"]
union ["Encounter, Performed": "Preventive Care Services - Established Office Visit, 18 and Up"]
union ["Encounter, Performed": "Preventive Care Services-Initial Office Visit, 18 and Up"]
union ["Encounter, Performed": "Home Healthcare Services"] ) ValidEncounter
where ValidEncounter.relevantPeriod during "Measurement Period"
PROPOSED:
value set "Online Assessments" (2.16.840.1.113883.3.464.1003.101.12.1089)
value set "Telephone Visits" (2.16.840.1.113883.3.464.1003.101.12.1080)
"Qualifying Encounters":
( ["Encounter, Performed": "Office Visit"]
union ["Encounter, Performed": "Annual Wellness Visit"]
union ["Encounter, Performed": "Preventive Care Services - Established Office Visit, 18 and Up"]
union ["Encounter, Performed": "Preventive Care Services-Initial Office Visit, 18 and Up"]
union ["Encounter, Performed": "Home Healthcare Services"]
union ["Encounter, Performed": "Online Assessments"]
union ["Encounter, Performed": "Telephone Visits"]
) ValidEncounter
where ValidEncounter.relevantPeriod during "Measurement Period"
The following change applies to CMS125 and CMS130:
CURRENT:
define "Initial Population":
... and exists ( AdultOutpatientEncounters."Qualifying Encounters"
union "Telehealth Services" )
define "Telehealth Services":
( ["Encounter, Performed": "Online Assessments"]
union ["Encounter, Performed": "Telephone Visits"] ) TelehealthEncounter
where TelehealthEncounter.relevantPeriod during "Measurement Period"
PROPOSED:
define "Initial Population":
... and exists AdultOutpatientEncounters."Qualifying Encounters"
The following change applies to CMS165:
CURRENT:
define "Initial Population":
...and ( exists AdultOutpatientEncounters."Qualifying Encounters"
or exists ( ( ["Encounter, Performed": "Telephone Visits"]
union ["Encounter, Performed": "Online Assessments"] ) Telehealth
where Telehealth.relevantPeriod during "Measurement Period" ) )
PROPOSED:
define "Initial Population":
... and exists AdultOutpatientEncounters."Qualifying Encounters
The following change applies to CMS122 and CMS134.
CURRENT:
define "Initial Population":
... and exists ( AdultOutpatientEncounters."Qualifying Encounters"
union "Telehealth Services" )
define "Telehealth Services":
["Encounter, Performed": "Telephone Visits"] TelehealthEncounter
where TelehealthEncounter.relevantPeriod during "Measurement Period"
PROPOSED:
define "Initial Population":
... and exists "Qualifying Encounters"
define "Qualifying Encounters"
( ["Encounter, Performed": "Office Visit"]
union ["Encounter, Performed": "Annual Wellness Visit"]
union ["Encounter, Performed": "Preventive Care Services - Established Office Visit, 18 and Up"]
union ["Encounter, Performed": "Preventive Care Services-Initial Office Visit, 18 and Up"]
union ["Encounter, Performed": "Home Healthcare Services"]
union ["Encounter, Performed": "Telephone Visits"]
) ValidEncounter
where ValidEncounter.relevantPeriod during "Measurement Period"
Rationale for Change:
This proposed solution will simplify repeated logic across multiple measures to ensure consistency.